Previous
About HAP: Enumerating homotopy 2-types
next

A 2-type is a CW-space X whose homotopy groups are trivial in dimensions n=0 and n>2. As explained in a previous page the homotopy type of such a space can be captured algebraically by a cat1-group G.

Let us consider two 2-types X, Y represented by cat1-groups G, H. If X and Y are homotopy equivalent then there exists a sequence of morphisms of cat1-groups

G --> K1 <-- K2 --> K3 <-- ... --> Kn <-- H

each morphism inducing an isomorphism on homotopy  groups.  When such a sequence of morphisms exists we say that G is quasi-isomorphic to H. We have the following result.

THEOREM

The 2-types X and Y are homotopy equivalent if and only if the  associated cat1-groups G and H are quasi-isomorphic.

We mention that crossed modules are a well-known alternative algebraic formulation of cat1-groups. There is a categorical equivalence between these two algebraic notions. We have opted to work through the language of cat1-groups.
All small cat1-groups G have been listed up to isomorphism in the GAP package XMod. For example, the following commands produce a list L of all of the 62 non-isomorphic cat1-groups whose underlying group has order 16.
gap> LoadPackage("xmod");
gap> L:=[];;
gap> for n in [1..NrSmallGroups(16)] do
> k:=Cat1Select(16,n);;
> for m in [1..k] do
> G:=Cat1Select(16,n,m);;
> Add(L,XmodToHAP(G));
> od;od;

gap> Length(L);
62
The following commands use the first and second homotopy groups to prove that the list L contains at least 37 distinct quasi-isomorphism types.
gap> Invariants:=function(G)
> local inv;
> inv:=[];
> inv[1]:=IdGroup(HomotopyGroup(G,1));
> inv[2]:=IdGroup(HomotopyGroup(G,2));
> return inv;
> end;;

gap> C:=Classify(L,Invariants);;
gap> Length(C);
37
The following commands use second and third integral homology in conjunction with the first two homotopy groups to prove that the list L contains at least 49 distinct quasi-isomorphism types.
gap> Invariants:=function(G)
> local inv;
> inv:=[];
> inv[1]:=IdGroup(HomotopyGroup(G,1));
> inv[2]:=IdGroup(HomotopyGroup(G,2));
> inv[3]:=Homology(G,2);
> inv[4]:=Homology(G,3);
> return inv;
> end;;

gap> C:=Classify(L,Invariants);;
gap> Length(C);
49
Similar commands can be used to prove that there are exactly 6 distinct quasi-isomorphism types of cat1-group of order 4. There is obviously just one quasi-isomorphism types of cat1-groups of order 1. Hence the following commands show that the above list L contains at most 52 (=6+1+45) distinct quasi-isomorphism types.
gap> Q:=List(L,QuasiIsomorph);;
gap> List(Q,Size);
[ 16, 16, 16, 16, 16, 16, 1, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 4, 16,
  4, 16, 16, 16, 16, 16, 16, 16, 16, 16, 16, 4, 4, 16, 4, 16, 4, 16, 4, 4,
  16, 16, 16, 16, 4, 16, 4, 16, 4, 16, 16, 4, 16, 16, 16, 16, 16, 4, 16, 4,
  1, 16, 4 ]
Previous Page
Contents
Next page